feat: add various system and theme icons, configuration files, and support assets

squashfs-root/usr/share/zsh/vendor-completions/_bootctl

@@ -0,0 +1,86 @@
+#compdef bootctl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+__bootctl() {
+    bootctl --no-pager $@ 2>/dev/null
+}
+
+_bootctl_comp_ids() {
+    local expl
+    local -a ids
+    __bootctl list | while read a b; do
+        if [[ "$a" == "id:" ]]; then
+            ids+="$b"
+        fi
+    done
+    _wanted id expl 'boot id' compadd "$@" -a ids
+}
+
+_bootctl_set-default() {
+    _bootctl_comp_ids
+}
+
+_bootctl_set-oneshot() {
+    _bootctl_comp_ids
+}
+
+_bootctl_unlink() {
+    _bootctl_comp_ids
+}
+
+_bootctl_reboot-to-firmware() {
+    local -a _completions
+    _completions=( yes no )
+    typeset -U _completions
+   _describe 'possible values' _completions
+}
+
+(( $+functions[_bootctl_commands] )) || _bootctl_commands()
+{
+    local -a _bootctl_cmds
+    _bootctl_cmds=(
+        "status:Show status of installed systemd-boot and EFI variables"
+        "install:Install systemd-boot to the ESP and EFI variables"
+        "update:Update systemd-boot in the ESP and EFI variables"
+        "remove:Remove systemd-boot from the ESP and EFI variables"
+        "is-installed:Test whether systemd-boot is installed in the ESP"
+        "random-seed:Initialize random seed in ESP and EFI variables"
+        "systemd-efi-options:Query or set system options string in EFI variable"
+        "reboot-to-firmware:Query or set reboot-to-firmware EFI flag"
+        "list:List boot loader entries"
+        "set-default:Set the default boot loader entry"
+        "set-oneshot:Set the default boot loader entry only for the next boot"
+        "set-timeout:Set the menu timeout"
+        "set-timeout-oneshot:Set the menu timeout for the next boot only"
+        "unlink:Remove boot loader entry"
+        "cleanup:Remove files in ESP not referenced in any boot entry"
+    )
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'bootctl command' _bootctl_cmds || compadd "$@"
+    else
+        local curcontext="$curcontext"
+        cmd="${${_bootctl_cmds[(r)$words[1]:*]%%:*}}"
+        if (( $+functions[_bootctl_$cmd] )); then
+            _bootctl_$cmd
+        else
+            _message "no more options"
+        fi
+    fi
+}
+
+_arguments \
+    {-h,--help}'[Prints a short help text and exits.]' \
+    '--version[Prints a short version string and exits.]' \
+    '--esp-path=[Path to the EFI System Partition (ESP)]:path:_directories' \
+    '--boot-path=[Path to the $BOOT partition]:path:_directories' \
+    {-p,--print-esp-path}'[Print path to the EFI system partition]' \
+    {-x,--print-boot-path}'[Print path to the $BOOT partition]' \
+    '--make-machine-id-directory=[Control creation and deletion of the top-level machine ID directory.]:options:(yes no auto)' \
+    '--no-variables[Do not touch EFI variables]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--graceful[Do not fail when locating ESP or writing fails]' \
+    '--dry-run[Dry run (unlink and cleanup)]' \
+    '--root=[Operate under the specified directory]:PATH' \
+    '--image=[Operate on the specified image]:PATH' \
+    '--install-source[Where to pick files when using --root=/--image=]:options:(image host auto)' \
+    '*::bootctl command:_bootctl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_busctl

@@ -0,0 +1,287 @@
+#compdef busctl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+# busctl(1) completion                               -*- shell-script -*-
+#
+# This file is part of systemd.
+#
+# systemd is free software; you can redistribute it and/or modify it
+# under the terms of the GNU Lesser General Public License as published by
+# the Free Software Foundation; either version 2.1 of the License, or
+# (at your option) any later version.
+#
+# systemd is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public License
+# along with systemd; If not, see <https://www.gnu.org/licenses/>.
+
+(( $+functions[_busctl_commands] )) || _busctl_commands()
+{
+    local -a _busctl_cmds
+    _busctl_cmds=(
+        "list:List bus names"
+        "status:Show bus service, process or bus owner credentials"
+        "monitor:Show bus traffic"
+        "capture:Capture bus traffic"
+        "tree:Show object tree of service"
+        "introspect:Introspect object"
+        "call:Call a method"
+        "get-property:Get property value"
+        "set-property:Set property value"
+    )
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'busctl command' _busctl_cmds || compadd "$@"
+    else
+        local curcontext="$curcontext"
+        cmd="${${_busctl_cmds[(r)$words[1]:*]%%:*}}"
+        curcontext="${curcontext%:*:*}:busctl-${cmd}:"
+        if (( $+functions[_busctl_$cmd] )); then
+            _busctl_$cmd
+        else
+            _message "no more options"
+        fi
+    fi
+}
+
+__busctl() {
+    busctl $_bus_address --no-pager --no-legend "$@" 2>/dev/null
+}
+
+__dbus_matchspec() {
+    # https://dbus.freedesktop.org/doc/dbus-specification.html#message-bus-routing
+    _values -s, 'rules' \
+        'type[Match on message type]:type:(signal method_call method_return error)' \
+        'eavesdrop[Include unicast messages]:bool:(true false)' \
+        'sender[Match messages sent by a particular sender]:sender:{compadd $(_busctl_get_service_names)}'\
+        'interface[Match messages sent over or to a particular interface]:interface' \
+        'member[Match messages which have the given method or signal name]:member' \
+        'path[Match messages which are sent from or to the given object]:path' \
+        'path_namespace[Match messages which are sent from or to the given namespace]:namespace' \
+        'destination[Match messaged sent to the given unique name]:unique name:{compadd $(_busctl_get_unique_names)}'
+}
+
+(( $+functions[_busctl_get_json] )) || _busctl_get_json()
+{
+    local -a _json_forms
+    _json_forms=( $(__busctl --json=help; echo help) )
+    _values 'format' $_json_forms
+}
+
+(( $+functions[_busctl_get_service_names] )) || _busctl_get_service_names()
+{
+    local -a bus_names
+    bus_names=( $(__busctl call \
+        "org.freedesktop.DBus"  \
+        "/org/freedesktop/DBus" \
+        "org.freedesktop.DBus"  \
+        ListNames) )
+    echo ${(Q)bus_names[3,-1]}
+}
+
+(( $+functions[_busctl_get_unique_names] )) || _busctl_get_unique_names()
+{
+    local -a bus_names
+    local NAME OTHER
+    __busctl --unique list |
+    while read NAME OTHER; do
+        echo $NAME
+    done
+}
+
+(( $+functions[_busctl_get_objects] )) || _busctl_get_objects()
+{
+    local -a objects
+    local name="$1"
+    objects=($(__busctl --list tree $name ))
+    echo $objects
+}
+
+(( $+functions[_busctl_get_interfaces] )) || _busctl_get_interfaces()
+{
+    local NAME TYPE OTHER
+    __busctl introspect "$1" "$2" |
+    while read NAME TYPE OTHER; do
+        if [[ ${TYPE} == "interface" ]]; then
+            echo ${NAME}
+        fi
+    done
+}
+
+(( $+functions[_busctl_get_members] )) || _busctl_get_members()
+{
+    local member="$4"
+    local required="$5"
+    local NAME TYPE SIGNATURE VALUE FLAGS
+    __busctl introspect "$1" "$2" "$3" |
+    while read NAME TYPE SIGNATURE VALUE FLAGS; do
+        [[ -z "$member" || ${TYPE} == "$member" ]] &&
+        [[ -z "$required" || "${${(os: :)FLAGS}}" == $~required ]] &&
+        echo ${NAME#.}
+    done
+}
+
+(( $+functions[_busctl_get_signature] )) || _busctl_get_signature()
+{
+    local NAME TYPE SIGNATURE VALUE FLAGS
+    __busctl introspect "$1" "$2" "$3" |
+    while read NAME TYPE SIGNATURE VALUE FLAGS; do
+        if [[ ${NAME#.} == "$4" ]]; then
+            [[ ${SIGNATURE} != "-" ]] && echo ${SIGNATURE}
+        fi
+    done
+}
+
+(( $+functions[_busctl_status] )) || _busctl_status()
+{
+    local expl
+    _wanted busname expl 'busname' compadd "$@" - $(_busctl_get_service_names)
+}
+
+(( $+functions[_busctl_monitor] )) || _busctl_monitor()
+{
+    local expl
+    _wanted busname expl 'busname' compadd "$@" - $(_busctl_get_service_names)
+}
+
+(( $+functions[_busctl_tree] )) || _busctl_tree()
+{
+    local expl
+    _wanted busname expl 'busname' compadd "$@" - $(_busctl_get_service_names)
+}
+
+(( $+functions[_busctl_introspect] )) || _busctl_introspect()
+{
+    local expl
+    case $CURRENT in
+        2)
+            _wanted busname expl 'busname' \
+            compadd "$@" - $(_busctl_get_service_names)
+            ;;
+        3)
+            _wanted path expl 'path' \
+            compadd "$@" - $(_busctl_get_objects $words[2])
+            ;;
+        4)
+            _wanted interface expl 'interface' \
+            compadd "$@" - $(_busctl_get_interfaces $words[2,3])
+            ;;
+        *)
+            _message "no more options"
+    esac
+}
+
+(( $+functions[_busctl_call] )) || _busctl_call()
+{
+    local expl
+    case $CURRENT in
+        2)
+            _wanted busname expl 'busname' \
+            compadd "$@" - $(_busctl_get_service_names)
+            ;;
+        3)
+            _wanted path expl 'path' \
+            compadd "$@" - $(_busctl_get_objects $words[2])
+            ;;
+        4)
+            _wanted interface expl 'interface' \
+            compadd "$@" - $(_busctl_get_interfaces $words[2,3])
+            ;;
+        5)
+            _wanted method expl 'method' \
+            compadd "$@" - $(_busctl_get_members $words[2,4] "method")
+            ;;
+        6)
+            compadd "$@" - $(_busctl_get_signature $words[2,5])
+            ;;
+        *)
+            _message "no more options"
+    esac
+}
+
+(( $+functions[_busctl_get-property] )) || _busctl_get-property()
+{
+    local expl
+    case $CURRENT in
+        2)
+            _wanted busname expl 'busname' \
+            compadd "$@" - $(_busctl_get_service_names)
+            ;;
+        3)
+            _wanted path expl 'path' \
+            compadd "$@" - $(_busctl_get_objects $words[2])
+            ;;
+        4)
+            _wanted interface expl 'interface' \
+            compadd "$@" - $(_busctl_get_interfaces $words[2,3])
+            ;;
+        5)
+            _wanted property expl 'property' \
+            compadd "$@" - $(_busctl_get_members $words[2,4] "property")
+            ;;
+        *)
+            _message "no more options"
+    esac
+}
+
+(( $+functions[_busctl_set-property] )) || _busctl_set-property()
+{
+    local expl
+    case $CURRENT in
+        2)
+            _wanted busname expl 'busname' \
+            compadd "$@" - $(_busctl_get_service_names)
+            ;;
+        3)
+            _wanted path expl 'path' \
+            compadd "$@" - $(_busctl_get_objects $words[2])
+            ;;
+        4)
+            _wanted interface expl 'interface' \
+            compadd "$@" - $(_busctl_get_interfaces $words[2,3])
+            ;;
+        5)
+            _wanted property expl 'property' \
+            compadd "$@" - $(_busctl_get_members $words[2,4] "property" "*writable*")
+            ;;
+        6)
+            compadd "$@" - $(_busctl_get_signature $words[2,5])
+            ;;
+        *)
+            _message "no more options"
+    esac
+}
+
+local -a _modes; _modes=("--user" "--system")
+# Use the last mode (they are exclusive and the last one is used).
+local _bus_address=${${words:*_modes}[(R)(${(j.|.)_modes})]}
+local curcontext=$curcontext state line
+_arguments \
+    {-h,--help}'[Prints a short help text and exits.]' \
+    '--version[Prints a short version string and exits.]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-legend[Do not show the headers and footers]' \
+    '--system[Connect to system manager]' \
+    '--user[Connect to user service manager]' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
+    '--address=[Connect to the bus specified by address]:address' \
+    '--show-machine[Show machine ID column in list]' \
+    '--unique[Only show unique names]' \
+    '--acquired[Only show acquired names]' \
+    '--activatable[Only show activatable names]' \
+    '--match=[Only show matching messages]:match:__dbus_matchspec' \
+    '--list[Do not show tree, but simple object path list]' \
+    {-q,--quiet}'[Do not show method call reply]'\
+    '--verbose[Show result values in long format]' \
+    '--xml-interface[Dump the XML description in introspect command]' \
+    '--json=[Show result values in long format]:format:_busctl_get_json' \
+    '-j[Show pretty json in interactive sessions, short json otherwise]' \
+    '--expect-reply=[Expect a method call reply]:boolean:(1 0)' \
+    '--auto-start=[Auto-start destination service]:boolean:(1 0)' \
+    '--allow-interactive-authorization=[Allow interactive authorization for operation]:boolean:(1 0)' \
+    '--timeout=[Maximum time to wait for method call completion]:timeout (seconds)' \
+    '--augment-creds=[Extend credential data with data read from /proc/$PID]:boolean:(1 0)' \
+    '*::busctl command:_busctl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_hostnamectl

@@ -0,0 +1,95 @@
+#compdef hostnamectl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_hostnamectl_hostname] )) ||
+_hostnamectl_hostname() {
+    if (( CURRENT <= 3 )); then
+        _message "new hostname"
+    else
+        _message "no more options"
+    fi
+}
+
+(( $+functions[_hostnamectl_icon-name] )) ||
+_hostnamectl_icon-name() {
+    if (( CURRENT <= 3 )); then
+        _message "new icon name"
+    else
+        _message "no more options"
+    fi
+}
+
+(( $+functions[_hostnamectl_chassis] )) ||
+_hostnamectl_chassis() {
+    if (( CURRENT <= 3 )); then
+        _chassis=( desktop laptop convertible server tablet handset watch embedded vm container )
+        _describe chassis _chassis
+    else
+        _message "no more options"
+    fi
+}
+
+(( $+functions[_hostnamectl_deployment] )) ||
+_hostnamectl_deployment() {
+    if (( CURRENT <= 3 )); then
+        _message "new environment"
+    else
+        _message "no more options"
+    fi
+}
+
+(( $+functions[_hostnamectl_location] )) ||
+_hostnamectl_location() {
+    if (( CURRENT <= 3 )); then
+        _message "new location"
+    else
+        _message "no more options"
+    fi
+}
+
+(( $+functions[_hostnamectl_commands] )) ||
+_hostnamectl_commands() {
+    local -a _hostnamectl_cmds
+    _hostnamectl_cmds=(
+        "status:Show current hostname settings"
+        "hostname:Get/set system hostname"
+        "icon-name:Get/set icon name for host"
+        "chassis:Get/set chassis type for host"
+        "deployment:Get/set deployment environment for host"
+        "location:Get/set location for host"
+    )
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'hostnamectl commands' _hostnamectl_cmds || compadd "$@"
+    else
+        local curcontext="$curcontext"
+        cmd="${${_hostnamectl_cmds[(r)$words[1]:*]%%:*}}"
+        if (( $#cmd )); then
+            if [[ $cmd == status ]]; then
+                _message "no options"
+            else
+                _hostnamectl_$cmd
+            fi
+        else
+            _message "unknown hostnamectl command: $words[1]"
+        fi
+    fi
+}
+
+(( $+functions[_hostnamectl_get_json] )) || _hostnamectl_get_json()
+{
+    local -a _json_forms
+    _json_forms=( $(hostnamectl --json=help 2>/dev/null) )
+    _values 'format' $_json_forms
+}
+
+_arguments -s \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--transient[Only set transient hostname]' \
+    '--static[Only set static hostname]' \
+    '--pretty[Only set pretty hostname]' \
+    '--no-ask-password[Do not prompt for password]' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
+    '--json[Shows output formatted as JSON]:format:_hostnamectl_get_json' \
+    '*::hostnamectl commands:_hostnamectl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_journalctl

@@ -0,0 +1,144 @@
+#compdef journalctl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_journalctl_fields] )) ||
+_journalctl_fields() {
+    local -a journal_fields
+    journal_fields=(MESSAGE{,_ID} PRIORITY CODE_{FILE,LINE,FUNC}
+                    ERRNO SYSLOG_{FACILITY,IDENTIFIER,PID}
+                    _{P,U,G}ID _COMM _EXE _CMDLINE
+                    _AUDIT_{SESSION,LOGINUID}
+                    _SYSTEMD_{CGROUP,SESSION,UNIT,OWNER_UID}
+                    _SYSTEMD_USER_UNIT USER_UNIT
+                    _SELINUX_CONTEXT _SOURCE_REALTIME_TIMESTAMP
+                    _{BOOT,MACHINE}_ID _HOSTNAME _TRANSPORT
+                    _KERNEL_{DEVICE,SUBSYSTEM}
+                    _UDEV_{SYSNAME,DEVNODE,DEVLINK}
+                    __CURSOR __{REALTIME,MONOTONIC}_TIMESTAMP)
+    case $_jrnl_none in
+        yes) _values -s '=' 'possible fields' \
+                "${journal_fields[@]}:value:_journalctl_field_values ${words[CURRENT]%%=*}" ;;
+        *)  _describe 'possible fields' journal_fields ;;
+    esac
+}
+
+(( $+functions[_journalctl_none] )) ||
+_journalctl_none() {
+    local -a _commands _files _jrnl_none
+    # Setting use-cache will slow this down considerably
+    _commands=( ${(f)"$(_call_program commands "$service $_sys_service_mgr -F _EXE" 2>/dev/null)"} )
+    _jrnl_none='yes'
+    _alternative : \
+        'files:/dev files:_files -W /dev -P /dev/' \
+        'commands:commands:compadd -a _commands' \
+        'fields:fields:_journalctl_fields'
+}
+
+(( $+functions[_journalctl_field_values] )) ||
+_journalctl_field_values() {
+    local -a _fields cmd
+    cmd=("journalctl $_sys_service_mgr" "-F ${@[-1]}" "2>/dev/null" )
+    _fields=$(_call_program fields $cmd[@])
+    _fields=${_fields//'\'/'\\'}
+    _fields=${_fields//':'/'\:'}
+    _fields=( ${(f)_fields} )
+    typeset -U _fields
+    _describe 'possible values' _fields
+}
+
+(( $+functions[_journalctl_boots] )) ||
+_journalctl_boots() {
+  local -a _bootid _previousboots
+  _bootid=( ${(f)"$(_call_program bootid "$service -F _BOOT_ID")"}  )
+  _previousboots=( -{1..${#_bootid}} )
+  _alternative : \
+    "offsets:boot offsets:compadd -a '_previousboots[1,-2]'" \
+    "bootid:boot ids:compadd -a _bootid"
+}
+
+(( $+functions[_journalctl_facilities] )) ||
+_journalctl_facilities() {
+  local -a _journalctl_facilities
+  _journalctl_facilities=(kern user mail daemon auth syslog lpr news uucp cron authpriv ftp local0 local1 local2 local3 local4 local5 local6 local7)
+  _describe 'possible values' _journalctl_facilities
+}
+
+# Build arguments for "journalctl" to be used in completion.
+# Use both --user and --system modes, they are not exclusive.
+local -a _modes; _modes=(--user --system)
+local -a _modes_with_arg; _modes_with_arg=(--directory -D --file -M --machine --root)
+typeset -a _sys_service_mgr
+local w k v i=0 n=$#words
+while (( i++ < n )); do
+    w=$words[$i]
+    if (( $_modes[(I)$w] )); then
+        _sys_service_mgr+=($w)
+    else
+        # Handle options with arguments. "--key=value" and "--key value".
+        k=${w%%=*}
+        if (( ${_modes_with_arg[(I)$k]} )); then
+            v=${w#*=}
+            if [[ "$k" != "$w" ]]; then
+                # "--key=value" style.
+                _sys_service_mgr+=($w)
+            else
+                # "--key value" style.
+                _sys_service_mgr+=($w ${words[((++i))]})
+            fi
+        fi
+    fi
+done
+_arguments -s \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    --no-hostname"[Don't show the hostname of local log messages]" \
+    {-l,--full}'[Show long fields in full]' \
+    {-a,--all}'[Show all fields, including long and unprintable]' \
+    {-f,--follow}'[Follow journal]' \
+    {-e,--pager-end}'[Jump to the end of the journal in the pager]' \
+    {-n+,--lines=}'[Number of journal entries to show]:integer' \
+    '--no-tail[Show all lines, even in follow mode]' \
+    {-r,--reverse}'[Reverse output]' \
+    {-o+,--output=}'[Change journal output mode]:output modes:_sd_outputmodes' \
+    {-x,--catalog}'[Show explanatory texts with each log line]' \
+    {-q,--quiet}"[Don't show privilege warning]" \
+    {-m,--merge}'[Show entries from all available journals]' \
+    {-b+,--boot=}'[Show data only from the specified boot or offset]::boot id or offset:_journalctl_boots' \
+    '--list-boots[List boots ordered by time]' \
+    {-k,--dmesg}'[Show only kernel messages from the current boot]' \
+    {-u+,--unit=}'[Show data only from the specified unit]:units:_journalctl_field_values _SYSTEMD_UNIT' \
+    '--user-unit=[Show data only from the specified user session unit]:units:_journalctl_field_values USER_UNIT' \
+    {-p+,--priority=}'[Show only messages within the specified priority range]:priority:_journalctl_field_values PRIORITY' \
+    '--facility=[Filter messages by facility]:facility:_journalctl_facilities' \
+    {-t+,--identifier=}'[Filter messages by syslog identifier]:identifier:_journalctl_field_values SYSLOG_IDENTIFIER' \
+    {-c+,--cursor=}'[Start showing entries from the specified cursor]:cursors:_journalctl_field_values __CURSORS' \
+    '--cursor-file=[Show entries using cursor store in file]:file:_files' \
+    '--after-cursor=[Start showing entries from after the specified cursor]:cursors:_journalctl_field_values __CURSORS' \
+    '--since=[Start showing entries on or newer than the specified date]:YYYY-MM-DD HH\:MM\:SS' \
+    '--until=[Stop showing entries on or older than the specified date]:YYYY-MM-DD HH\:MM\:SS' \
+    {-F,--field=}'[List all values a certain field takes]:Fields:_journalctl_fields' \
+    '--system[Show system and kernel messages]' \
+    '--user[Show messages from user services]' \
+    '(--directory -D -M --machine --root --file)'{-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
+    '(--directory -D -M --machine --root --file)'{-D+,--directory=}'[Show journal files from directory]:directories:_directories' \
+    '(--directory -D -M --machine --root --file)--root=[Operate on catalog hierarchy under specified directory]:directories:_directories' \
+    '(--directory -D -M --machine --root)*--file=[Operate on specified journal files]:file:_files' \
+    '--disk-usage[Show total disk usage]' \
+    '--dump-catalog[Dump messages in catalog]' \
+    '--flush[Flush all journal data from /run into /var]' \
+    '--force[Force recreation of the FSS keys]' \
+    '--header[Show journal header information]' \
+    '--interval=[Time interval for changing the FSS sealing key]:time interval' \
+    '--list-catalog[List messages in catalog]' \
+    '--new-id128[Generate a new 128 Bit ID]' \
+    '--rotate[Request immediate rotation of the journal files]' \
+    '--setup-keys[Generate a new FSS key pair]' \
+    '--sync[Synchronize unwritten journal messages to disk]' \
+    '--update-catalog[Update binary catalog database]' \
+    '--vacuum-files=[Leave only the specified number of journal files]:integer' \
+    '--vacuum-size=[Reduce disk usage below specified size]:bytes' \
+    '--vacuum-time=[Remove journal files older than specified time]:time' \
+    '--verify-key=[Specify FSS verification key]:FSS key' \
+    '--verify[Verify journal file consistency]' \
+    '*::default: _journalctl_none'

squashfs-root/usr/share/zsh/vendor-completions/_kernel-install

@@ -0,0 +1,27 @@
+#compdef kernel-install
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_kernel-install_images] )) ||
+_kernel-install_images(){
+    if [[ "$words[2]" == "remove" ]]; then
+        _message 'No more options'
+    else
+        _path_files -W /boot/ -P /boot/ -g "vmlinuz-*"
+    fi
+}
+
+(( $+functions[_kernel-install_kernels] )) ||
+_kernel-install_kernels(){
+    read _MACHINE_ID < /etc/machine-id
+    _kernel=( /lib/modules/[0-9]* )
+    if [[ "$cmd" == "remove" && -n "$_MACHINE_ID" ]]; then
+        _kernel=( "/boot/$_MACHINE_ID"/[0-9]* )
+    fi
+    _kernel=( ${_kernel##*/} )
+    _describe "installed kernels" _kernel
+}
+
+_arguments \
+    '1::add or remove:(add remove)' \
+    '2::kernel versions:_kernel-install_kernels' \
+    '3::kernel images:_kernel-install_images'

squashfs-root/usr/share/zsh/vendor-completions/_localectl

@@ -0,0 +1,98 @@
+#compdef localectl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_localectl_set-locale] )) ||
+_localectl_set-locale() {
+    local -a _locales locale_fields
+    locale_fields=(LANG LANGUAGE LC_CTYPE LC_NUMERIC LC_TIME \
+                   LC_COLLATE LC_MONETARY LC_MESSAGES LC_PAPER \
+                   LC_NAME LC_ADDRESS LC_TELEPHONE \
+                   LC_MEASUREMENT LC_IDENTIFICATION)
+    # LC_ALL is omitted on purpose
+
+    local expl suf
+    _locales=( ${(f)"$(_call_program locales "$service" list-locales)"} )
+    if [[ -prefix 1 *\= ]]; then
+        compset -P1 '*='
+        local conf=${PREFIX%%\=*}
+        _wanted locales expl "locales configs" \
+            _combination localeconfs  confs=$conf locales "$@" -
+    else
+        compadd -S '=' $locale_fields
+    fi
+}
+
+(( $+functions[_localectl_set-keymap] )) ||
+_localectl_set-keymap() {
+    local -a _keymaps
+    if (( CURRENT <= 3 )); then
+        _keymaps=( ${(f)"$(_call_program locales "$service" list-keymaps)"} )
+        _describe keymaps _keymaps
+    else
+        _message "no more options"
+    fi
+}
+
+(( $+functions[_localectl_set-x11-keymap] )) ||
+_localectl_set-x11-keymap() {
+    if (( $+commands[pkg-config] )); then
+        local -a _file _layout _model _variant _options
+        local _xorg_lst
+        _xorg_lst=${"$($commands[pkg-config] xkeyboard-config --variable=xkb_base)"}
+        _file=( ${(ps:\n\!:)"$(<$_xorg_lst/rules/base.lst)"} )
+        _layout=( ${${${(M)${(f)_file[2]}:#  *}#  }%% *} )
+        _model=( ${${${(M)${(f)_file[1]}:#  *}#  }%% *} )
+        _variant=( ${${${(M)${(f)_file[3]}:#  *}#  }%% *} )
+        _options=( ${${${(M)${(f)_file[4]}:#  *}#  }%% *} )
+        #_layout=( ${(f)"$( echo $_file[1] | awk '/^  / {print $1}' )"} )
+        #_model=( ${(f)"$(echo $_file[2] | awk '/^  / {print $1}')"} )
+        #_variant=( ${(f)"$(echo $_file[3] | awk '/^  / {print $1}')"} )
+        #_options=( ${(f)"$(echo ${_file[4]//:/\\:} | awk '/^  / {print $1}')"} )
+
+        case $CURRENT in
+            2) _describe layouts _layout ;;
+            3) _describe models _model;;
+            4) _describe variants _variant;;
+            5) _describe options _options;;
+            *) _message "no more options"
+        esac
+    fi
+}
+
+(( $+functions[_localectl_commands] )) ||
+_localectl_commands() {
+    local -a _localectl_cmds
+    _localectl_cmds=(
+        'status:Show current locale settings'
+        'set-locale:Set system locale'
+        'list-locales:Show known locales'
+        'set-keymap:Set virtual console keyboard mapping'
+        'list-keymaps:Show known virtual console keyboard mappings'
+        'set-x11-keymap:Set X11 keyboard mapping'
+        'list-x11-keymap-models:Show known X11 keyboard mapping models'
+        'list-x11-keymap-layouts:Show known X11 keyboard mapping layouts'
+        'list-x11-keymap-variants:Show known X11 keyboard mapping variants'
+        'list-x11-keymap-options:Show known X11 keyboard mapping options'
+    )
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'localectl command' _localectl_cmds
+    else
+        local curcontext="$curcontext"
+        cmd="${${_localectl_cmds[(r)$words[1]:*]%%:*}}"
+        if (( $+functions[_localectl_$cmd] )); then
+            _localectl_$cmd
+        else
+            _message "unknown localectl command: $words[1]"
+        fi
+    fi
+}
+
+_arguments \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    "--no-convert[Don't convert keyboard mappings]" \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-ask-password[Do not prompt for password]' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machine' \
+    '*::localectl commands:_localectl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_loginctl

@@ -0,0 +1,182 @@
+#compdef loginctl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_loginctl_all_sessions] )) ||
+_loginctl_all_sessions() {
+    local session description
+    loginctl --no-legend list-sessions | while read -r session description; do
+        _sys_all_sessions+=( "$session" )
+        _sys_all_sessions_descr+=( "${session}:$description" )
+    done
+}
+
+(( $+functions[_loginctl_all_users] )) ||
+_loginctl_all_users() {
+    local uid description
+    loginctl --no-legend list-users | while read -r uid description; do
+        _sys_all_users+=( "$uid" )
+        _sys_all_users_descr+=( "${uid}:$description" )
+    done
+}
+
+(( $+functions[_loginctl_all_seats] )) ||
+_loginctl_all_seats() {
+    local seat description
+    loginctl --no-legend list-seats | while read -r seat description; do
+        _sys_all_seats+=( "$seat" )
+        _sys_all_seats_descr+=( "${seat}:$description" )
+    done
+}
+
+local fun
+# Completion functions for SESSIONS
+for fun in session-status show-session activate lock-session unlock-session terminate-session kill-session ; do
+    (( $+functions[_loginctl_$fun] )) ||
+_loginctl_$fun() {
+    local -a _sys_all_sessions{,_descr}
+
+	_sys_all_sessions=( "self" )
+	_sys_all_sessions_descr=( "self:alias for the current session" )
+
+    _loginctl_all_sessions
+    for _ignore in $words[2,-1]; do
+        _sys_all_sessions[(i)$_ignore]=()
+        _sys_all_sessions_descr[(i)$_ignore:*]=()
+    done
+
+    if zstyle -T ":completion:${curcontext}:systemd-sessions" verbose; then
+        _describe -t systemd-sessions session _sys_all_sessions_descr _sys_all_sessions "$@"
+    else
+        local expl
+        _wanted systemd-sessions expl session compadd "$@" -a _sys_all_sessions
+    fi
+}
+done
+
+# Completion functions for USERS
+for fun in user-status show-user enable-linger disable-linger terminate-user kill-user ; do
+    (( $+functions[_loginctl_$fun] )) ||
+_loginctl_$fun() {
+    local -a _sys_all_users{,_descr}
+    zstyle -a ":completion:${curcontext}:users" users _sys_all_users
+
+    if ! (( $#_sys_all_users )); then
+        _loginctl_all_users
+    fi
+
+    for _ignore in $words[2,-1]; do
+        _sys_all_users[(i)$_ignore]=()
+        _sys_all_users_descr[(i)$_ignore:*]=()
+    done
+
+    # using the common tag `users' here, not rolling our own `systemd-users' tag
+    if zstyle -T ":completion:${curcontext}:users" verbose; then
+        _describe -t users user ${_sys_all_users_descr:+_sys_all_users_descr} _sys_all_users "$@"
+    else
+        local expl
+        _wanted users expl user compadd "$@" -a _sys_all_users
+    fi
+}
+done
+
+# Completion functions for SEATS
+(( $+functions[_loginctl_seats] )) ||
+_loginctl_seats() {
+    local -a _sys_all_seats{,_descr}
+
+	_sys_all_seats=( "self" )
+	_sys_all_seats_descr=( "self:alias for the current seat" )
+
+    _loginctl_all_seats
+    for _ignore in $words[2,-1]; do
+        _sys_all_seats[(i)$_ignore]=()
+        _sys_all_seats_descr[(i)$_ignore:*]=()
+    done
+
+    if zstyle -T ":completion:${curcontext}:systemd-seats" verbose; then
+        _describe -t systemd-seats seat _sys_all_seats_descr _sys_all_seats "$@"
+    else
+        local expl
+        _wanted systemd-seats expl seat compadd "$@" -a _sys_all_seats
+    fi
+}
+for fun in seat-status show-seat terminate-seat ; do
+    (( $+functions[_loginctl_$fun] )) ||
+_loginctl_$fun() { _loginctl_seats }
+done
+
+# Completion functions for ATTACH
+(( $+functions[_loginctl_attach] )) ||
+_loginctl_attach() {
+    _arguments -w -C -S -s \
+               ':seat:_loginctl_seats' \
+               '*:device:_files'
+}
+
+# no loginctl completion for:
+# [STANDALONE]='list-sessions list-users list-seats flush-devices'
+
+(( $+functions[_loginctl_commands] )) ||
+_loginctl_commands() {
+    local -a _loginctl_cmds
+    _loginctl_cmds=(
+        "list-sessions:List sessions"
+        "session-status:Show session status"
+        "show-session:Show properties of one or more sessions"
+        "activate:Activate a session"
+        "lock-session:Screen lock one or more sessions"
+        "unlock-session:Screen unlock one or more sessions"
+        "lock-sessions:Screen lock all current sessions"
+        "unlock-sessions:Screen unlock all current sessions"
+        "terminate-session:Terminate one or more sessions"
+        "kill-session:Send signal to processes of a session"
+        "list-users:List users"
+        "user-status:Show user status"
+        "show-user:Show properties of one or more users"
+        "enable-linger:Enable linger state of one or more users"
+        "disable-linger:Disable linger state of one or more users"
+        "terminate-user:Terminate all sessions of one or more users"
+        "kill-user:Send signal to processes of a user"
+        "list-seats:List seats"
+        "seat-status:Show seat status"
+        "show-seat:Show properties of one or more seats"
+        "attach:Attach one or more devices to a seat"
+        "flush-devices:Flush all device associations"
+        "terminate-seat:Terminate all sessions on one or more seats"
+    )
+
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'loginctl command' _loginctl_cmds || compadd "$@"
+    else
+        local curcontext="$curcontext" _ignore
+
+        cmd="${${_loginctl_cmds[(r)$words[1]:*]%%:*}}"
+
+        if (( $#cmd )); then
+            curcontext="${curcontext%:*:*}:loginctl-${cmd}:"
+
+            _call_function ret _loginctl_$cmd || _message 'no more arguments'
+        else
+            _message "unknown loginctl command: $words[1]"
+        fi
+        return ret
+    fi
+}
+
+
+_arguments -s \
+    {-h,--help}'[Show help]' \
+    '--version[Show package version]' \
+    \*{-p+,--property=}'[Show only properties by this name]:unit property' \
+    {-a,--all}'[Show all properties, including empty ones]' \
+    '--kill-whom=[Whom to send signal to]:killwhom:(main control all)' \
+    {-s+,--signal=}'[Which signal to send]:signal:_signals' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machine:_sd_machines' \
+    {-l,--full}'[Do not ellipsize output]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-legend[Do not show the headers and footers]' \
+    '--no-ask-password[Do not ask for system passwords]' \
+    {-n+,--lines=}'[Number of journal entries to show]' \
+    {-o+,--output=}'[Change journal output mode]:output modes:_sd_outputmodes' \
+    '*::loginctl command:_loginctl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_networkctl

@@ -0,0 +1,60 @@
+#compdef networkctl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_networkctl_commands] )) ||
+    _networkctl_commands() {
+        local -a _networkctl_cmds
+        _networkctl_cmds=(
+            'list:List existing links'
+            'status:Show information about the specified links'
+            'lldp:Show Link Layer Discovery Protocol status'
+            'label:Show address labels'
+            'delete:Delete virtual netdevs'
+            'edit:Edit network configurations'
+            'cat:Cat network configurations'
+            'up:Bring devices up'
+            'down:Bring devices down'
+            'renew:Renew dynamic configurations'
+            'forcerenew:Trigger DHCP reconfiguration of all connected clients'
+            'reconfigure:Reconfigure interfaces'
+            'reload:Reload .network and .netdev files'
+        )
+        if (( CURRENT == 1 )); then
+            _describe -t commands 'networkctl command' _networkctl_cmds
+        else
+            local curcontext="$curcontext"
+            local -a _links
+            cmd="${${_networkctl_cmds[(r)$words[1]:*]%%:*}}"
+            case $cmd in
+                (list|status|up|down|cat|edit|lldp|delete|renew|forcerenew|reconfigure)
+                    for link in ${(f)"$(_call_program links networkctl list --no-legend)"}; do _links+=($link[(w)2]:$link); done
+                    if [[ -n "$_links" ]]; then
+                        _describe -t links 'links' _links _links $( [[ $cmd == (edit|cat) ]] && print -- -P@ )
+                    else
+                        _message "no links"
+                    fi
+                    ;;
+                *)
+                    _message "no more options"
+                    ;;
+            esac
+        fi
+    }
+
+(( $+functions[_networkctl_get_json] )) || _networkctl_get_json()
+{
+    local -a _json_forms
+    _json_forms=( $(networkctl --json=help 2>/dev/null) )
+    _values 'format' $_json_forms
+}
+
+_arguments \
+    {-a,--all}'[Show all links with status]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-legend[Do not print the column headers]' \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--drop-in=[Use the given drop-in file name]' \
+    '--no-reload[Do not reload the network manager state when editing]' \
+    '--json[Shows output formatted as JSON]:format:_networkctl_get_json' \
+    '*::networkctl commands:_networkctl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_sd_hosts_or_user_at_host

@@ -0,0 +1,6 @@
+#autoload
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+_alternative \
+    'users-hosts:: _user_at_host' \
+    'hosts:: _hosts'

squashfs-root/usr/share/zsh/vendor-completions/_sd_outputmodes

@@ -0,0 +1,6 @@
+#autoload
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+local -a _output_opts
+_output_opts=(short short-full short-iso short-iso-precise short-precise short-monotonic short-unix short-delta verbose export json json-pretty json-sse json-seq cat with-unit)
+_describe -t output 'output mode' _output_opts || compadd "$@"

squashfs-root/usr/share/zsh/vendor-completions/_sd_unit_files

@@ -0,0 +1,10 @@
+#autoload
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+_sd_unit_files() {
+    local files expl
+    files=( '*:files:->files' )
+
+    _description files expl 'unit file'
+    _files "$expl[@]" -g '*.(automount|device|mount|path|service|socket|swap|target|timer)'
+}

squashfs-root/usr/share/zsh/vendor-completions/_systemctl

@@ -0,0 +1,542 @@
+#compdef systemctl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_systemctl_commands] )) || _systemctl_commands()
+{
+    local expl i
+
+    local -a unit_commands=(
+        # Unit Commands
+        "list-automounts:List automounts"
+        "list-paths:List paths"
+        "list-sockets:List sockets"
+        "list-timers:List timers"
+        "list-units:List units"
+        "start:Start (activate) one or more units"
+        "stop:Stop (deactivate) one or more units"
+        "reload:Reload one or more units"
+        "restart:Start or restart one or more units"
+        "condrestart:Restart one or more units if active"
+        "try-restart:Restart one or more units if active"
+        "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
+        "force-reload:Reload one or more units if possible, otherwise restart if active"
+        "try-reload-or-restart:Reload one or more units if possible, otherwise restart if active"
+        "isolate:Start one unit and stop all others"
+        "kill:Send signal to processes of a unit"
+        "is-active:Check whether units are active"
+        "is-failed:Check whether units are failed"
+        "status:Show runtime status of one or more units"
+        "show:Show properties of one or more units/jobs or the manager"
+        "cat:Show the source unit files and drop-ins"
+        "set-property:Sets one or more properties of a unit"
+        "service-log-level:Get or set the logging threshold for service"
+        "service-log-target:Get or set the logging target for service"
+        "help:Show documentation for specified units"
+        "reset-failed:Reset failed state for all, one, or more units"
+        "list-dependencies:Show unit dependency tree"
+        "clean:Remove configuration, state, cache, logs or runtime data of units"
+        "bind:Bind mount a path from the host into a unit's namespace"
+        "mount-image:Mount an image from the host into a unit's namespace"
+        "whoami:Determines as part of which unit the command is being invoked"
+    )
+
+    local -a machine_commands=(
+        # Machine Commands
+        "list-machines:List the host and all running local containers"
+    )
+
+    local -a unit_file_commands=(
+        # Unit File Commands
+        "list-unit-files:List installed unit files"
+        "enable:Enable one or more unit files"
+        "disable:Disable one or more unit files"
+        "reenable:Reenable one or more unit files"
+        "preset:Enable/disable one or more unit files based on preset configuration"
+        "preset-all:Enable/disable all unit files based on preset configuration"
+        "is-enabled:Check whether unit files are enabled"
+        "mask:Mask one or more units"
+        "unmask:Unmask one or more units"
+        "link:Link one or more units files into the search path"
+        "revert:Revert unit files to their vendor versions"
+        "add-wants:Add Wants= dependencies to a unit"
+        "add-requires:Add Requires= dependencies to a unit"
+        "set-default:Set the default target"
+        "get-default:Query the default target"
+        "edit:Edit one or more unit files"
+    )
+
+    local -a job_commands=(
+        # Job Commands
+        "list-jobs:List jobs"
+        "cancel:Cancel all, one, or more jobs"
+    )
+
+    local -a environment_commands=(
+        # Environment Commands
+        "show-environment:Dump environment"
+        "set-environment:Set one or more environment variables"
+        "unset-environment:Unset one or more environment variables"
+        "import-environment:Import environment variables set on the client"
+    )
+
+    local -a manager_state_commands=(
+        # Manager State Commands
+        "daemon-reload:Reload systemd manager configuration"
+        "daemon-reexec:Reexecute systemd manager"
+        "log-level:Get or set the log level"
+        "log-target:Get or set the log target"
+        "service-watchdogs:Get or set the state of software watchdogs"
+    )
+
+    local -a system_commands=(
+        # System Commands
+        "is-system-running:Query overall status of the system"
+        "default:Enter system default mode"
+        "rescue:Enter system rescue mode"
+        "emergency:Enter system emergency mode"
+        "halt:Shut down and halt the system"
+        "suspend:Suspend the system"
+        "poweroff:Shut down and power-off the system"
+        "reboot:Shut down and reboot the system"
+        "soft-reboot:Shut down and reboot the userspace"
+        "kexec:Shut down and reboot the system with kexec"
+        "exit:Ask for user instance termination"
+        "switch-root:Change root directory"
+        "hibernate:Hibernate the system"
+        "hybrid-sleep:Hibernate and suspend the system"
+        "suspend-then-hibernate:Suspend the system for a period of time, and then hibernate it"
+    )
+
+    local -a groups=( unit machine unit_file job environment manager_state system )
+    local -a _systemctl_cmds
+    for i in $groups; do
+        _systemctl_cmds+=( "${(@P)${:-"${i}_commands"}}" )
+    done
+
+    if (( CURRENT == 1 )); then
+        _tags ${^groups//_/-}-commands
+        while _tags; do
+            for i in $groups; do
+                if _requested ${i//_/-}-commands; then
+                    _describe -t ${i//_/-}-commands "${i//_/ } command" ${i}_commands \
+                        && ret=0
+                fi
+            done
+        done
+    else
+        local curcontext="$curcontext"
+
+        cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
+        # Deal with any aliases
+        case $cmd in
+            condrestart) cmd="try-restart";;
+            force-reload) cmd="try-reload-or-restart";;
+        esac
+
+        if (( $#cmd )); then
+            curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
+
+            local update_policy
+            zstyle -s ":completion:${curcontext}:" cache-policy update_policy
+            if [[ -z "$update_policy" ]]; then
+                zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
+            fi
+
+            _call_function ret _systemctl_$cmd || _message 'no more arguments'
+        else
+            _message "unknown systemctl command: $words[1]"
+        fi
+        return ret
+    fi
+}
+
+# @todo _systemd-run has a helper with the same name, so we must redefine
+__systemctl()
+{
+    command systemctl $_sys_service_mgr --full --legend=no --no-pager --plain "$@" 2>/dev/null
+}
+
+
+# Fills the unit list
+(( $+functions[_systemctl_all_units] )) ||
+    _systemctl_all_units()
+{
+    if _cache_invalid SYS_ALL_UNITS$_sys_service_mgr || ! _retrieve_cache SYS_ALL_UNITS$_sys_service_mgr;
+    then
+        _sys_all_units=( ${${(f)"$(__systemctl list-units --all)"}%% *} )
+        _store_cache SYS_ALL_UNITS$_sys_service_mgr _sys_all_units
+    fi
+}
+
+# Fills the unit list including all file units
+(( $+functions[_systemctl_really_all_units] )) ||
+    _systemctl_really_all_units()
+{
+    local -a all_unit_files;
+    local -a really_all_units;
+    if _cache_invalid SYS_REALLY_ALL_UNITS$_sys_service_mgr || ! _retrieve_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr;
+    then
+        all_unit_files=( ${${(f)"$(__systemctl list-unit-files)"}%% *} )
+        _systemctl_all_units
+        really_all_units=($_sys_all_units $all_unit_files)
+        _sys_really_all_units=(${(u)really_all_units})
+        _store_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr _sys_really_all_units
+    fi
+}
+
+(( $+functions[_filter_units_by_property] )) ||
+    _filter_units_by_property() {
+        local property=$1 value=$2; shift 2
+        local -a units; units=("${(q-)@}")
+        local -A props
+        props=(${(f)"$(_call_program units "$service $_sys_service_mgr show --no-pager --property=\"Id,$property\" -- ${units} 2>/dev/null")"})
+        echo -E - "${(@g:o:)${(k@)props[(Re)$property=$value]}#Id=}"
+    }
+
+(( $+functions[_systemctl_get_non_template_names] )) ||
+    _systemctl_get_non_template_names() {
+        _systemctl_really_all_units
+        print -r - ${_sys_really_all_units:#*@.*}
+    }
+
+(( $+functions[_systemctl_get_template_names] )) ||
+    _systemctl_get_template_names() {
+        local pathkind=systemd-search-${_sys_service_mgr##*--}-unit
+        print -r - ${(s-:-)^$(_call_program $pathkind systemd-path $pathkind)}/*@.(${(~j.|.)$(__systemctl --type=help)})(N:t:r)
+    }
+
+(( $+functions[_systemctl_active_units] )) ||
+    _systemctl_active_units()  {
+        local pattern
+        if zstyle -T ":completion:$curcontext" use-pattern; then
+            pattern="$PREFIX*$SUFFIX"
+        fi
+        _sys_active_units=(  ${${(f)"$(__systemctl list-units $pattern)"}%% *} )
+    }
+
+(( $+functions[_systemctl_startable_units] )) ||
+    _systemctl_startable_units(){
+        local pattern
+        if zstyle -T ":completion:$curcontext" use-pattern; then
+            pattern="$PREFIX*$SUFFIX"
+        fi
+        _sys_startable_units=( $( _filter_units_by_property ActiveState inactive $(
+                                      _filter_units_by_property CanStart yes ${${${(f)"$(
+      __systemctl list-unit-files --state enabled,enabled-runtime,linked,linked-runtime,static,indirect,disabled,generated,transient $pattern
+      __systemctl list-units --state inactive,failed $pattern
+    )"}:#*@.*}%%[[:space:]]*}
+                                                            )) )
+    }
+
+(( $+functions[_systemctl_restartable_units] )) ||
+    _systemctl_restartable_units(){
+        local pattern
+        if zstyle -T ":completion:$curcontext" use-pattern; then
+            pattern="$PREFIX*$SUFFIX"
+        fi
+        _sys_restartable_units=( $( _filter_units_by_property CanStart yes ${${${(f)"$(
+    __systemctl list-unit-files --state enabled,disabled,static $pattern
+    __systemctl list-units $pattern
+  )"}:#*@.*}%%[[:space:]]*} ) )
+    }
+
+(( $+functions[_systemctl_failed_units] )) ||
+    _systemctl_failed_units()  {_sys_failed_units=( ${${(f)"$(__systemctl list-units --state=failed)"}%% *} ) }
+
+(( $+functions[_systemctl_unit_state] )) ||
+    _systemctl_unit_state() {
+        setopt localoptions extendedglob
+        local pattern
+        if zstyle -T ":completion:$curcontext" use-pattern; then
+            pattern="$PREFIX*$SUFFIX"
+        fi
+        typeset -gA _sys_unit_state
+        _sys_unit_state=( ${=${${(f)"$(__systemctl list-unit-files $pattern)"}%%[[:space:]]#}% *} )
+    }
+
+local fun
+# Completion functions for ALL_UNITS
+for fun in cat mask ; do
+    (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
+    {
+        _systemctl_really_all_units
+        _wanted systemd-units expl unit \
+                compadd "$@" -a - _sys_really_all_units
+    }
+done
+
+# Completion functions for NONTEMPLATE_UNITS
+for fun in is-active is-failed is-enabled status show preset help list-dependencies edit revert add-wants add-requires set-property; do
+    (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
+    {
+        _wanted systemd-units expl unit \
+                compadd "$@" - $(_systemctl_get_non_template_names)
+    }
+done
+
+# Completion functions for ENABLED_UNITS
+(( $+functions[_systemctl_disable] )) || _systemctl_disable()
+{
+    local _sys_unit_state; _systemctl_unit_state
+    _wanted systemd-units expl 'enabled unit' \
+            compadd "$@" - ${(k)_sys_unit_state[(R)enabled]}
+}
+
+(( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
+{
+    local _sys_unit_state; _systemctl_unit_state
+    _wanted systemd-units expl 'enabled/disabled unit' \
+            compadd "$@" - ${(k)_sys_unit_state[(R)(enabled|disabled)]} $(_systemctl_get_template_names)
+}
+
+# Completion functions for DISABLED_UNITS
+(( $+functions[_systemctl_enable] )) || _systemctl_enable()
+{
+    local _sys_unit_state; _systemctl_unit_state
+    _wanted systemd-units expl 'disabled unit' \
+            compadd "$@" - ${(k)_sys_unit_state[(R)disabled]} $(_systemctl_get_template_names)
+}
+
+# Completion functions for FAILED_UNITS
+(( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
+{
+    local _sys_failed_units; _systemctl_failed_units
+    _wanted systemd-units expl 'failed unit' \
+            compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
+}
+
+# Completion functions for STARTABLE_UNITS
+(( $+functions[_systemctl_start] )) || _systemctl_start()
+{
+    local _sys_startable_units; _systemctl_startable_units
+    _wanted systemd-units expl 'startable unit' \
+            compadd "$@" - ${_sys_startable_units[*]}
+}
+
+# Completion functions for STOPPABLE_UNITS
+for fun in stop kill try-restart condrestart ; do
+    (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
+    {
+        local _sys_active_units; _systemctl_active_units
+        _wanted systemd-units expl 'stoppable unit' \
+                compadd "$@" - $( _filter_units_by_property CanStop yes \
+                                                            ${_sys_active_units[*]} )
+    }
+done
+
+(( $+functions[_systemctl_service-log-level] )) ||
+    _systemctl_service-log-level() {
+        local -a log_levels=( emerg alert crit err warning notice info debug )
+        local _sys_active_units; _systemctl_active_units
+        if (( CURRENT == 2 )); then
+            _wanted systemd-units expl 'active unit' \
+                compadd "$@" -a - _sys_active_units || _message "no units found"
+        else
+            compadd "$@" -a - log_levels
+        fi
+}
+
+(( $+functions[_systemctl_service-log-target] )) ||
+    _systemctl_service-log-target() {
+        local -a log_targets=( console kmsg journal syslog null auto )
+        local _sys_active_units; _systemctl_active_units
+        if (( CURRENT == 2 )); then
+            _wanted systemd-units expl 'active unit' \
+                compadd "$@" -a - _sys_active_units || _message "no units found"
+        else
+            compadd "$@" -a - log_targets
+        fi
+}
+
+# Completion functions for ISOLATABLE_UNITS
+(( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
+{
+    _systemctl_all_units
+    _wanted systemd-units expl 'isolatable unit' \
+            compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
+                                                        ${_sys_all_units[*]} )
+}
+
+# Completion functions for RELOADABLE_UNITS
+for fun in reload try-reload-or-restart force-reload ; do
+    (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
+    {
+        local _sys_active_units; _systemctl_active_units
+        _wanted systemd-units expl 'reloadable unit' \
+                compadd "$@" - $( _filter_units_by_property CanReload yes \
+                                                            ${_sys_active_units[*]} )
+    }
+done
+
+# Completion functions for RESTARTABLE_UNITS
+for fun in restart reload-or-restart ; do
+    (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
+    {
+        local _sys_restartable_units; _systemctl_restartable_units
+        _wanted systemd-units expl 'restartable unit' \
+                compadd "$@" - ${_sys_restartable_units[*]}
+    }
+done
+
+# Completion functions for MASKED_UNITS
+(( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
+{
+    local _sys_unit_state; _systemctl_unit_state
+    _wanted systemd-units expl 'masked unit' \
+            compadd "$@" - ${(k)_sys_unit_state[(R)masked]} || _message "no masked units found"
+}
+
+# Completion functions for JOBS
+(( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
+{
+    _wanted systemd-jobs expl job \
+            compadd "$@" - ${${(f)"$(__systemctl list-jobs)"}%% *} ||
+        _message "no jobs found"
+}
+
+# Completion functions for TARGETS
+(( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
+{
+    _wanted systemd-targets expl target \
+            compadd "$@" - ${${(f)"$(__systemctl list-unit-files --type target --all)"}%% *} ||
+        _message "no targets found"
+}
+
+# Completion functions for ENVS
+for fun in set-environment unset-environment ; do
+    (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
+    {
+        local fun=$0 ; fun=${fun##_systemctl_}
+        local suf
+        if [[ "${fun}" = "set-environment" ]]; then
+            suf='-S='
+        fi
+        _wanted systemd-environment expl 'environment variable' \
+                compadd "$@" ${suf} - ${${(f)"$(systemctl show-environment)"}%%=*}
+    }
+done
+
+(( $+functions[_systemctl_import-environment] )) || _systemctl_import-environment()
+{
+    _parameters
+}
+
+(( $+functions[_systemctl_link] )) || _systemctl_link() {
+        _sd_unit_files
+    }
+
+(( $+functions[_systemctl_switch-root] )) || _systemctl_switch-root() {
+        _files
+    }
+
+(( $+functions[_systemctl_bind] )) || _systemctl_bind() {
+        _files
+    }
+
+(( $+functions[_systemctl_mount-image] )) || _systemctl_mount-image() {
+        _files
+    }
+
+# no systemctl completion for:
+#    [STANDALONE]='daemon-reexec daemon-reload default
+#                  emergency exit halt kexec list-jobs list-units
+#                  list-unit-files poweroff reboot rescue show-environment'
+
+(( $+functions[_systemctl_caching_policy] )) ||
+    _systemctl_caching_policy()
+{
+    # rebuild if cache is more than a day old
+    [[ -n $1(#qNmd+1) ]] && return 0
+
+    local pathkind=systemd-search-${1##*--}-unit
+    for dir in ${(s-:-)^$(_call_program $pathkind systemd-path $pathkind)}; do
+        [[ $dir -nt $1 ]] && return 0
+    done
+
+    return 1
+}
+
+(( $+functions[_systemctl_unit_states] )) ||
+    _systemctl_unit_states() {
+        local -a _states
+        _states=("${(fo)$(__systemctl --state=help)}")
+        _values -s , "${_states[@]}"
+    }
+
+(( $+functions[_systemctl_unit_types] )) ||
+    _systemctl_unit_types() {
+        local -a _types
+        _types=("${(fo)$(__systemctl -t help)}")
+        _values -s , "${_types[@]}"
+    }
+
+(( $+functions[_systemctl_unit_properties] )) ||
+    _systemctl_unit_properties() {
+		local -a _sys_all_properties=( ${(f)"$(/usr/lib/systemd/systemd --no-pager --dump-bus-properties 2>/dev/null)"} )
+        _wanted systemd-unit-properties expl 'unit property' \
+			_values -s , "${_sys_all_properties[@]}"
+    }
+
+(( $+functions[_systemctl_job_modes] )) ||
+    _systemctl_job_modes() {
+        local -a _modes
+        _modes=(fail replace replace-irreversibly isolate ignore-dependencies ignore-requirements flush)
+        _values -s , "${_modes[@]}"
+    }
+
+(( $+functions[_systemctl_timestamp] )) ||
+    _systemctl_timestamp() {
+        local -a _styles
+        _styles=(help pretty us µs utc us+utc µs+utc)
+        _values -s , "${_styles[@]}"
+    }
+
+(( $+functions[_systemctl_check_inhibitors] )) ||
+    _systemctl_check_inhibitors() {
+        local -a _modes
+        _modes=(auto yes no)
+        _values -s , "${_modes[@]}"
+    }
+
+# Build arguments for "systemctl" to be used in completion.
+# Use the last mode, or --system (they are exclusive and the last one is used).
+local _sys_service_mgr=${words[(R)(--user|--system)]:---system}
+_arguments -s \
+    {-h,--help}'[Show help]' \
+    '--version[Show package version]' \
+    {-t+,--type=}'[List only units of a particular type]:unit type:_systemctl_unit_types' \
+    '--state=[Display units in the specified state]:unit state:_systemctl_unit_states' \
+    '--job-mode=[Specify how to deal with other jobs]:mode:_systemctl_job_modes' \
+    {-p+,--property=}'[Show only properties by specific name]:unit property:_systemctl_unit_properties' \
+    {-a,--all}'[Show all units/properties, including dead/empty ones]' \
+    '--reverse[Show reverse dependencies]' \
+    '--after[Show units ordered after]' \
+    '--before[Show units ordered before]' \
+    {-l,--full}"[Don't ellipsize unit names on output]" \
+    '--show-types[When showing sockets, show socket type]' \
+    '--check-inhibitors[Specify if inhibitors should be checked]:mode:_systemctl_check_inhibitors' \
+    {-q,--quiet}'[Suppress output]' \
+    '--no-warn[Suppress several warnings shown by default]' \
+    '--no-block[Do not wait until operation finished]' \
+    '--legend=no[Do not print a legend, i.e. the column headers and the footer with hints]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--system[Connect to system manager]' \
+    '--user[Connect to user service manager]' \
+    "--no-wall[Don't send wall message before halt/power-off/reboot]" \
+    '--global[Enable/disable/mask default user unit files globally]' \
+    "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
+    '--no-ask-password[Do not ask for system passwords]' \
+    '--kill-whom=[Whom to send signal to]:killwhom:(main control all)' \
+    {-s+,--signal=}'[Which signal to send]:signal:_signals' \
+    {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
+    '--root=[Enable/disable/mask unit files in the specified root directory]:directory:_directories' \
+    '--runtime[Enable/disable/mask unit files only temporarily until next reboot]' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-P,--privileged}'[Acquire privileges before execution]' \
+    {-n+,--lines=}'[Journal entries to show]:number of entries' \
+    {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
+    '--firmware-setup[Tell the firmware to show the setup menu on next boot]' \
+    '--plain[When used with list-dependencies, print output as a list]' \
+    '--failed[Show failed units]' \
+    '--timestamp=[Change format of printed timestamps]:style:_systemctl_timestamp' \
+    '*::systemctl command:_systemctl_commands'

squashfs-root/usr/share/zsh/vendor-completions/_systemd

@@ -0,0 +1,81 @@
+#compdef systemd-cat systemd-ask-password systemd-cgls systemd-cgtop systemd-detect-virt systemd-machine-id-setup systemd-notify systemd-tty-ask-password-agent
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+local curcontext="$curcontext" state lstate line
+case "$service" in
+    systemd-ask-password)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--icon=[Icon name]:icon name:' \
+            '--timeout=[Timeout in sec]:timeout (seconds):' \
+            '--no-tty[Ask question via agent even on TTY]' \
+            '--accept-cached[Accept cached passwords]' \
+            '--multiple[List multiple passwords if available]'
+        ;;
+    systemd-cat)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--version[Show package version.]' \
+            {-t+,--identifier=}'[Set syslog identifier.]:syslog identifier:' \
+            {-p+,--priority=}'[Set priority value.]:value:({0..7})' \
+            '--level-prefix=[Control whether level prefix shall be parsed.]:boolean:(1 0)' \
+            ':Message'
+        ;;
+    systemd-cgls)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--version[Show package version]' \
+            '--no-pager[Do not pipe output into a pager]' \
+            {-a,--all}'[Show all groups, including empty]' \
+            '-k[Include kernel threads in output]' \
+            ':cgroups:(cpuset cpu cpuacct memory devices freezer blkio)'
+        ;;
+    systemd-cgtop)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--version[Print version and exit]' \
+            '(-c -m -i -t)-p[Order by path]' \
+            '(-c -p -m -i)-t[Order by number of tasks]' \
+            '(-m -p -i -t)-c[Order by CPU load]' \
+            '(-c -p -i -t)-m[Order by memory load]' \
+            '(-c -m -p -t)-i[Order by IO load]' \
+            {-d+,--delay=}'[Specify delay]:delay:' \
+            {-n+,--iterations=}'[Run for N iterations before exiting]:number of iterations:' \
+            {-b,--batch}'[Run in batch mode, accepting no input]' \
+            '--depth=[Maximum traversal depth]:maximum depth:'
+        ;;
+    systemd-detect-virt)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--version[Show package version]' \
+            {-c,--container}'[Only detect whether we are run in a container]' \
+            {-v,--vm}'[Only detect whether we are run in a VM]' \
+            {-q,--quiet}"[Don't output anything, just set return value]"
+        ;;
+    systemd-machine-id-setup)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--version[Show package version]'
+        ;;
+    systemd-notify)
+        _arguments \
+            {-h,--help}'[Show this help]' \
+            '--version[Show package version]' \
+            '--ready[Inform the init system about service start-up completion.]' \
+            '--pid=[Inform the init system about the main PID of the daemon]:daemon main PID:_pids' \
+            '--status=[Send a free-form status string for the daemon to the init systemd]:status string:' \
+            '--booted[Returns 0 if the system was booted up with systemd]'
+        ;;
+    systemd-tty-ask-password-agent)
+        _arguments \
+            {-h,--help}'[Prints a short help text and exits.]' \
+            '--version[Prints a short version string and exits.]' \
+            '--list[Lists all currently pending system password requests.]' \
+            '--query[Process all currently pending system password requests by querying the user on the calling TTY.]' \
+            '--watch[Continuously process password requests.]' \
+            '--wall[Forward password requests to wall(1).]' \
+            '--plymouth[Ask question with plymouth(8).]' \
+            '--console[Ask question on /dev/console.]'
+        ;;
+    *) _message 'eh?' ;;
+esac

squashfs-root/usr/share/zsh/vendor-completions/_systemd-analyze

@@ -0,0 +1,123 @@
+#compdef systemd-analyze
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_systemd-analyze_verify] )) ||
+    _systemd-analyze_verify() {
+        _sd_unit_files
+    }
+
+(( $+functions[_systemd-analyze_cat-config] )) ||
+	_systemd-analyze_cat-config() {
+        _files -W '(/run/systemd/ /etc/systemd/ /usr/lib/systemd/)' -P 'systemd/'
+    }
+
+(( $+functions[_systemd-analyze_critical-chain] )) ||
+    _systemd-analyze_critical-chain() {
+        local -a _units
+        systemctl list-units --no-legend --no-pager --plain --all |
+        while read -r a b c; do
+            _units+=($a)
+        done
+        compadd -a _units
+    }
+
+(( $+functions[_systemd-analyze_security] )) ||
+    _systemd-analyze_security() {
+        _sd_unit_files
+    }
+
+(( $+functions[_systemd-analyze_syscall-filter] )) ||
+    _systemd-analyze_syscall-filter() {
+        local -a _groups
+        _groups=( $(systemd-analyze --quiet --no-pager syscall-filter | grep '^@') )
+        _describe -t groups 'syscall groups' _groups || compadd "$@"
+    }
+
+(( $+functions[_systemd-analyze_filesystems] )) ||
+    _systemd-analyze_filesystems() {
+        local -a _groups
+        _groups=( $(systemd-analyze --quiet --no-pager filesystems | grep '^@') )
+        _describe -t groups 'file system groups' _groups || compadd "$@"
+    }
+
+(( $+functions[_systemd-analyze_plot] )) ||
+    _systemd-analyze_plot() {
+        local -a _options
+        _options=( '--json=off' '--json=pretty' '--json=short' '--table' '--no-legend' )
+        _describe 'plot options' _options
+    }
+
+(( $+functions[_systemd-analyze_commands] )) ||
+    _systemd-analyze_commands(){
+        local -a _systemd_analyze_cmds
+        # Descriptions taken from systemd-analyze --help.
+        _systemd_analyze_cmds=(
+            'time:Print time spent in the kernel before reaching userspace'
+            'blame:Print list of running units ordered by time to init'
+            'critical-chain:Print a tree of the time critical chain of units'
+            'plot:Output SVG graphic showing service initialization, or raw time data in
+JSON or table format'
+            'dot:Dump dependency graph (in dot(1) format)'
+            'dump:Dump server status'
+            'cat-config:Cat systemd config files'
+            'unit-files:List files and symlinks for units'
+            'unit-paths:List unit load paths'
+            'exit-status:List known exit statuses'
+            'capability:List capability definitions'
+            'syscall-filter:List syscalls in seccomp filters'
+            'filesystems:List known filesystems'
+            'condition:Evaluate Condition*= and Assert*= assignments'
+            'verify:Check unit files for correctness'
+            'calendar:Validate repetitive calendar time events'
+            'timestamp:Parse a systemd syntax timestamp'
+            'timespan:Parse a systemd syntax timespan'
+            'security:Analyze security settings of a service'
+            'inspect-elf:Parse and print ELF package metadata'
+            # log-level, log-target, service-watchdogs have been deprecated
+        )
+
+        if (( CURRENT == 1 )); then
+            _describe "options" _systemd_analyze_cmds
+        else
+            local curcontext="$curcontext"
+            cmd="${${_systemd_analyze_cmds[(r)$words[1]:*]%%:*}}"
+            if (( $#cmd )); then
+                if (( $+functions[_systemd-analyze_$cmd] )) && (( CURRENT == 2 )); then
+                    _systemd-analyze_$cmd
+                else
+                    _message "no more options"
+                fi
+            else
+                _message "unknown systemd-analyze command: $words[1]"
+            fi
+        fi
+    }
+
+_arguments \
+    {-h,--help}'[Show help text]' \
+    '--version[Show package version]' \
+    '--system[Operate on system systemd instance]' \
+    '--user[Operate on user systemd instance]' \
+    '--global[Show global user instance config]' \
+    '--root=[Add support for root argument]:PATH' \
+    '--image=[Add support for discrete images]:PATH' \
+    '--recursive-errors=[When verifying a unit, control dependency verification]:MODE' \
+    '--offline=[Perform a security review of the specified unit files]:BOOL:(yes no)' \
+    '--threshold=[Set a value to compare the overall security exposure level with]: NUMBER' \
+    '--security-policy=[Use customized requirements to compare unit files against]: PATH' \
+    "--json=[Generate a JSON output of the security analysis table or plot's raw time data]:MODE:(pretty short off)" \
+    "--table=[Generate a table of plot's raw time data]" \
+    '--profile=[Include the specified profile in the security review of units]: PATH' \
+    '--no-pager[Do not pipe output into a pager]' \
+    "--no-legend[Do not show the headers and footers for plot's raw time data formats]" \
+    '--man=[Do (not) check for existence of man pages]:BOOL:(yes no)' \
+    '--generators=[Do (not) run unit generators]:BOOL:(yes no)' \
+    '--order[When generating graph for dot, show only order]' \
+    '--require[When generating graph for dot, show only requirement]' \
+    '--fuzz=[When printing the tree of the critical chain, print also services, which finished TIMESPAN earlier, than the latest in the branch]:TIMESPAN' \
+    '--from-pattern=[When generating a dependency graph, filter only origins]:GLOB' \
+    '--to-pattern=[When generating a dependency graph, filter only destinations]:GLOB' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machine:_sd_machines' \
+    '--quiet[Do not show hints]' \
+    '*::systemd-analyze commands:_systemd-analyze_commands'

squashfs-root/usr/share/zsh/vendor-completions/_systemd-delta

@@ -0,0 +1,17 @@
+#compdef systemd-delta
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_systemd-delta_types] )) ||
+_systemd-delta_types() {
+    local -a _delta_types
+    _delta_types=(masked equivalent redirected overridden unchanged)
+    _values -s , "${_delta_types[@]}"
+}
+
+_arguments \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--diff=[Show a diff when overridden files differ]:boolean:(1 0)' \
+    {-t+,--type=}'[Only display a selected set of override types]:types:_systemd-delta_types' \
+    ':SUFFIX:(tmpfiles.d sysctl.d systemd/system)'

squashfs-root/usr/share/zsh/vendor-completions/_systemd-inhibit

@@ -0,0 +1,36 @@
+#compdef systemd-inhibit
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+(( $+functions[_systemd-inhibit_commands] )) ||
+_systemd-inhibit_commands(){
+    if (( CURRENT == 1 )); then
+        compset -q
+        _normal
+    else
+        local n=${words[(b:2:i)[^-]*]}
+        if (( n <= CURRENT )); then
+            compset -n $n
+            _alternative \
+                'files:file:_files' \
+                'commands:command:_normal' && return 0
+        fi
+        _default
+    fi
+}
+
+(( $+functions[_systemd-inhibit_what] )) ||
+_systemd-inhibit_what() {
+    local _inhibit
+    _inhibit=(shutdown sleep idle handle-power-key handle-suspend-key handle-hibernate-key handle-lid-switch)
+    _values -s : "${_inhibit[@]}"
+}
+
+_arguments \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--what=[Operations to inhibit]:options:_systemd-inhibit_what' \
+    '--who=[A descriptive string who is inhibiting]:who is inhibiting:' \
+    '--why=[A descriptive string why is being inhibited]:reason for the lock:' \
+    '--mode=[One of block or delay]:lock mode:( block delay )' \
+    '--list[List active inhibitors]' \
+    '*:commands:_systemd-inhibit_commands'

squashfs-root/usr/share/zsh/vendor-completions/_systemd-path

@@ -0,0 +1,9 @@
+#compdef systemd-path
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+typeset -A sdpath=( ${$(systemd-path)/:/} )
+_arguments -S \
+	'(-h --help)'{-h,--help}'[Print help text and exit]' \
+	'(-v --version)'{-v,--version}'[Print a version string and exit]' \
+	'--suffix=[Append a suffix to the paths]' \
+	'*:pathname:compadd -k sdpath'

squashfs-root/usr/share/zsh/vendor-completions/_systemd-run

@@ -0,0 +1,81 @@
+#compdef systemd-run
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+# @todo _systemctl has a helper with the same name, so we must redefine
+__systemctl() {
+    local -a _modes
+    _modes=("--user" "--system")
+    systemctl ${words:*_modes} --full --no-legend --no-pager --plain "$@" 2>/dev/null
+}
+
+(( $+functions[__systemd-run_get_slices] )) ||
+    __systemd-run_get_slices () {
+        __systemctl list-units --all -t slice \
+            | { while read -r a b; do echo $a; done; };
+    }
+
+(( $+functions[__systemd-run_slices] )) ||
+    __systemd-run_slices () {
+        local -a _slices
+        _slices=(${(fo)"$(__systemd-run_get_slices)"})
+        typeset -U _slices
+        _describe 'slices' _slices
+    }
+
+_arguments \
+    {-G,--collect}'[Unload the transient unit after it completed]' \
+    '--description=[Description for unit]:description' \
+    '--gid=[Run as system group]:group:_groups' \
+    {-h,--help}'[Show help message]' \
+    {-H+,--host=}'[Operate on remote host]:[user@]host:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
+    '--nice=[Nice level]:nice level' \
+    '--no-ask-password[Do not query the user for authentication]' \
+    '--no-block[Do not synchronously wait for the unit start operation to finish]' \
+    '--on-active=[Run after SEC seconds]:SEC' \
+    '--on-boot=[Run SEC seconds after machine was booted up]:SEC' \
+    '--on-calendar=[Realtime timer]:SPEC' \
+    '--on-clock-change[Defines a trigger based on system clock jumps]' \
+    '--on-startup=[Run SEC seconds after systemd was first started]:SEC' \
+    '--on-timezone-change[Defines a trigger based on system timezone changes]' \
+    '--on-unit-active=[Run SEC seconds after the last activation]:SEC' \
+    '--on-unit-inactive=[Run SEC seconds after the last deactivation]:SEC' \
+    '--path-property=[Set path unit property]:NAME=VALUE' \
+    {-P,--pipe}'[Inherit standard input, output, and error]' \
+    {-p+,--property=}'[Set unit property]:NAME=VALUE:(( \
+                CPUAccounting= MemoryAccounting= BlockIOAccounting= SendSIGHUP= \
+                SendSIGKILL= MemoryLimit= CPUShares= BlockIOWeight= User= Group= \
+                DevicePolicy= KillMode= ExitType= DeviceAllow= BlockIOReadBandwidth= \
+                BlockIOWriteBandwidth= BlockIODeviceWeight= Nice= Environment= \
+                KillSignal= RestartKillSignal= FinalKillSignal= LimitCPU= LimitFSIZE= LimitDATA= \
+                LimitSTACK= LimitCORE= LimitRSS= LimitNOFILE= LimitAS= LimitNPROC= \
+                LimitMEMLOCK= LimitLOCKS= LimitSIGPENDING= LimitMSGQUEUE= \
+                LimitNICE= LimitRTPRIO= LimitRTTIME= PrivateTmp= PrivateDevices= \
+                PrivateNetwork= NoNewPrivileges= WorkingDirectory= RootDirectory= \
+                TTYPath= SyslogIdentifier= SyslogLevelPrefix= SyslogLevel= \
+                SyslogFacility= TimerSlackNSec= OOMScoreAdjust= ReadWritePaths= \
+                ReadOnlyPaths= InaccessiblePaths= EnvironmentFile= \
+                ProtectSystem= ProtectHome= RuntimeDirectory= PassEnvironment= \
+                ))' \
+    {-t,--pty}'[The service connects to the terminal]' \
+    {-q,--quiet}'[Suppresses additional informational output]' \
+    {-r,--remain-after-exit}'[Leave service around until explicitly stopped]' \
+    {-d,--same-dir}'[Run on the current working directory]' \
+    '--scope[Run this as scope rather than service]' \
+    '--send-sighup[Send SIGHUP when terminating]' \
+    '--service-type=[Service type]:type:(simple forking oneshot dbus notify idle)' \
+    {-E+,--setenv=}'[Set environment]:NAME=VALUE' \
+    {-S,--shell}'[requests an interactive shell in the current working directory]' \
+    '--slice=[Run in the specified slice]:slices:__systemd-run_slices' \
+    '--slice-inherit[Run in the inherited slice]' \
+    '--socket-property=[Set socket unit property]:NAME=VALUE' \
+    '--system[Run as system unit]' \
+    '--timer-property=[Set timer unit property]:NAME=VALUE' \
+    '--uid=[Run as system user]:user:_users' \
+    {-u+,--unit=}'[Run under the specified unit name]:unit name' \
+    '--user[Run as user unit]' \
+    '--version[Show package version]' \
+    '--wait=[Wait until service stopped again]' \
+    '--working-directory=[Run with the specified working directory]' \
+    '(-):command: _command_names -e' \
+    '*::arguments:_normal'

squashfs-root/usr/share/zsh/vendor-completions/_systemd-tmpfiles

@@ -0,0 +1,14 @@
+#compdef systemd-tmpfiles
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+_arguments \
+    {-h,--help}'[Show help]' \
+    '--version[Show package version]' \
+    '--create[Create, set ownership/permissions based on the config files.]' \
+    '--clean[Clean up all files and directories with an age parameter configured.]' \
+    '--remove[All files and directories marked with r, R in the configuration files are removed.]' \
+    '--boot[Execute actions only safe at boot]' \
+    '--prefix=[Only apply rules that apply to paths with the specified prefix.]' \
+    '--exclude-prefix=[Ignore rules that apply to paths with the specified prefix.]' \
+    '--root=[Operate on an alternate filesystem root]:directory:_directories' \
+    '*::files:_files'

squashfs-root/usr/share/zsh/vendor-completions/_timedatectl

@@ -0,0 +1,69 @@
+#compdef timedatectl
+# SPDX-License-Identifier: LGPL-2.1-or-later
+
+_timedatectl_set-timezone(){
+    local -a _timezones
+    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
+    compadd "$_timezones[@]"
+}
+
+_timedatectl_set-time(){
+    _message "YYYY-MM-DD HH:MM:SS"
+}
+
+_timedatectl_set-local-rtc(){
+    local -a _options
+    _options=(
+        '0:Maintain RTC in universal time'
+        '1:Maintain RTC in local time'
+    )
+    _describe options _options
+}
+
+_timedatectl_set-ntp(){
+    local -a _options
+    _options=(
+        '0:Disable NTP based network time configuration'
+        '1:Enable NTP based network time configuration'
+    )
+    _describe options _options
+}
+
+_timedatectl_command(){
+    local -a _timedatectl_cmds
+    _timedatectl_cmds=(
+        'status:Show current time settings'
+        'set-time:Set system time'
+        'set-timezone:Set system timezone'
+        'list-timezones:Show known timezones'
+        'timesync-status:Show status of systemd-timesyncd'
+        'show-timesync:Show properties of systemd-timesyncd'
+        'set-local-rtc:Control whether RTC is in local time'
+        'set-ntp:Control whether NTP is enabled'
+    )
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'timedatectl command' _timedatectl_cmds
+    else
+        local curcontext="$curcontext"
+        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
+        if (( $#cmd )); then
+            if (( $+functions[_timedatectl_$cmd] )); then
+                _timedatectl_$cmd
+            else
+                _message "no more options"
+            fi
+        else
+            _message "unknown timedatectl command: $words[1]"
+        fi
+    fi
+}
+
+_arguments -s \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-ask-password[Do not prompt for password]' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
+    '*::timedatectl commands:_timedatectl_command'